さあ、今回からは画面効果の付加（自機がやられた時に出る爆風）に移りたいと思います。ほんのチョットした事で、ゲームのプレイ感が大きく変わりますので、ぜひとも色々と試して下さいね♪ まずbuffer 3に新たに爆風の画像を読み込みます。次に、いつも通り『*SYOKIKA』の所に初期の自機数を追加します。 次に『*MAIN』メインルーチンですが、ココにまたも1つサブルーチン『gosub *MASSAGE』を追加します。このサブルーチンでゲームのスコアや自機の残数等々の画面表示を行います。但し今回は、まだスコアを追加していないので、自機残数表示と自機がやられた時の爆風の表示処理のみです。 更に今回は、自機がやられた後しばらくの間、爆風表示や敵等を表示させる為にいくつかの条件式を追加しています。（ゲームオーバー時の判断処理もココで行います） 次に『*TAMAMOVE』と『*UFOTAMA』の自機との当たり判定の部分を一部変更します。前回までは、ぶつかった場所に爆風もどきを表示して終わりだったのですが、今回は爆風発生のサブルーチン『*MESSAGEBORN』に飛ばします。今後、敵をやっつけた時の爆風等を追加する時にも、このサブルーチンを利用しますが、今回はコレだけです・・・。 次に『*MESSAGEBORN』ですが、今回は自機がやられた時の爆風なので爆風を表示する座標を取得して終わりです。今後、敵の爆風処理にも利用します。 さあ、『*MESSAGE』ここが今回のメインかなぁ・・・・って言っても大した事はしてません・・・・(^^; 『gzoom』命令を使って自機画像を縮小コピーして画面左下に表示します。この横に変数『ml』を利用して自機の残数を表示します。 次の部分が、いよいよ爆風の表示部分です。『*TAMAMOVE』と『*UFOTAMA』の部分で自機がやられた時に、変数『mmf』に値を代入します。この値が０になるまで爆風表示部分を実行します。『*MESSAGEBORN』で取得した座標に爆風画像をコピーします。この時『mybomx=mybomx+1\8』この部分でmybomxの値を0,1,2,3,4,5,6,7,0,1,2,3,4,5,6,7・・・・と変化させ、読み込むキャラの画像を右に右にと移動させてアニメーション処理をしています。次の行の『if mybomx=7 : mybomy=1』の部分ではmybomxが7になったらＹ座標を一段下げて２列目頭からキャラの画像を読む様にしています。これで連続して１６枚の画像を順次表示（アニメーション）する事ができます♪ 最後にゲームオーバー処理ですが、今回は特に何もせず『end』命令でスクリプト実行を終了しています。本来なら、フェードアウトさせたりゲームオーバーのロゴ表示をしたり、スタートメニューに戻ったり、等々手を加えるべきでしょうが今回は省略です(^^; 敵の爆風表示も、基本的には同じように『MESSAGEBORN』の所で表示座標を取得（配列変数を利用します）して『MESSAGE』の部分で爆風の表示を行う事で対応できます。複数の爆風を用意して、それぞれを使い分ける事も可能ですので、色々と試してみて下さいね♪ 尚、分かりにくい場所があれば、掲示板やメールにてご質問下さい m(_ _)m 下記のスクリプトの一部または全部において転用は自由とさせていただきますので、色々と数字を換えてお試し下さい♪ 下記スクリプトをHSPのスクリプトエディターにコピペでお使いいただけます。 |
#define SHOTMAX 2 ;自機弾最大数
#define ENEMYMAX 12 ;敵機最大数
#define TAMAMAX 36 ;敵弾最大数
buffer 3,,,1
picload "bomb1.bmp"
buffer 2,,,1
picload "cruiser.bmp"
screen 0,640,480,1,dispx-640/2,dispy-480/2:cls 4 : title "space cruiser"
font "ＭＳ 明朝",20
gmode 2
*SYOKIKA
mx=300 : my=400 ;自機の初期位置
lv=1 ;初期レベル
myl=1 ;自機生存の有無
uf=10 ;UFO生存の有無（UFOの硬さも表現しています）
ux=160 : uy=60 ;UFOの初期位置
usx=6 ;UFOの移動初速度（Ｘ軸）
usy=8 ;UFOの移動初速度（Ｙ軸）
us=1 ;UFOの加速量
utsx=30 ;UFO弾の移動初速度（Ｘ軸）
utsy=6 ;UFO弾の移動初速度（Ｙ軸）
gcnt=1 ;ゲームカウンターの初期値
ml=3 ;初期の自機数
dim sf,SHOTMAX ;自弾の有無
dim sx,SHOTMAX ;自弾のＸ座標
dim sy,SHOTMAX ;自弾のＹ座標
dim ef,ENEMYMAX ;敵の硬さ
dim ex,ENEMYMAX ;敵のＸ座標
dim ey,ENEMYMAX ;敵のＹ座標
dim et,ENEMYMAX ;敵発生からのカウンター
dim esx,ENEMYMAX ;敵のＸ軸移動量
dim esy,ENEMYMAX ;敵のＹ軸移動量
dim tf,TAMAMAX ;敵弾の有無
dim tx,TAMAMAX ;敵弾のＸ座標
dim ty,TAMAMAX ;敵弾のＹ座標
dim tk,TAMAMAX ;敵弾の種類（垂直OR斜頚）
dim td,TAMAMAX ;敵弾の弾道（方向）
dim ts,TAMAMAX ;敵弾の移動速度
*MAIN ;メインループ
palcolor 0 : boxf 0,0,640,480
gosub *MESSAGE
if myl>0 : gosub *JIKI
gosub *TAMA
if enemy=0 : gosub *TEKI
gosub *TEKIMOVE
gosub *TAMAMOVE
gosub *UFO
gosub *UFOTAMA
redraw 1 : redraw 2 : await 30
gcnt+
if gres=0 : goto *MAIN
gwt+
if gwt<100 : goto *MAIN
myl=1 : gwt=0 : gres=0 : mx=300 : my=400 : sf=0 : ff=0
repeat TAMAMAX : tf.cnt=0 : loop
if ml<1 : goto *GAMEOVER
goto *MAIN
*JIKI ;自機の移動・ショットキーチェック
stick bt,5 : k- : if k<1 : if bt&16 : ff=1 : k=3
mxv=(bt&4!0):mxv-=(bt&1!0)
mx+=mxv*8
if mx<0 : mx=0
if mx>580 : mx=580
pos mx,my : gcopy 2,0,32,64,64
return
*TAMA ;自機弾の移動・表示
repeat SHOTMAX
if ff>0 : if sf.cnt=0 : ff- : sf.cnt=1 : sx.cnt=mx+16 : sy.cnt=my-20
if sf.cnt=0 : continue
sy.cnt-=12 : if sy.cnt<-32 : sf.cnt=0
pos sx.cnt,sy.cnt : gcopy 2,96,0,32,32
loop
return
*TEKI ;敵の出現
repeat ENEMYMAX
if cnt<12 {
if cnt<10 {
if cnt<8 {
if cnt<6 {
if cnt<4 {
if cnt<2 { ef.cnt=1 : ex.cnt=cnt*100+100 : ey.cnt=80
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32
}else{ ef.cnt=1 : ex.cnt=cnt-2*100+100 : ey.cnt=130
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32 }
}else{ ef.cnt=1 : ex.cnt=cnt-4*100+100 : ey.cnt=180
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32 }
}else{ ef.cnt=1 : ex.cnt=cnt-5*100+300 : ey.cnt=80
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32 }
}else{ ef.cnt=1 : ex.cnt=cnt-7*100+300 : ey.cnt=130
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32 }
}else{ ef.cnt=1 : ex.cnt=cnt-9*100+300 : ey.cnt=180
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32 }
}
esx.cnt=5 : esy.cnt=5 : et.cnt=0
enemy=1
loop
return
*TEKIMOVE ;敵の移動処理・当たり判定
repeat ENEMYMAX
if ef.cnt<1 : continue
et.cnt++
if cnt<6 {
ex.cnt-=esx.cnt : if et.cnt>20 : et.cnt=-20 : esx.cnt=-esx.cnt
ey.cnt+=esy.cnt : if (ey.cnt>200)|(ey.cnt<50) : esy.cnt=-esy.cnt
}else{
ex.cnt+=esx.cnt : if et.cnt>20 : et.cnt=-20 : esx.cnt=-esx.cnt
ey.cnt+=esy.cnt : if (ey.cnt>200)|(ey.cnt<50) : esy.cnt=-esy.cnt
}
ent=cnt
repeat SHOTMAX
if sf.cnt=0 : continue
dx=(ex.ent+16)-(sx.cnt+16) : if dx<0 : dx=-dx
dy=(ey.ent+16)-(sy.cnt+16) : if dy<0 : dy=-dy
if dx<10 : if dy<10 {
ef.ent- : sf.cnt- : pos ex.ent,ey.ent : palcolor 255 : mes "●"
}
loop
rnd tam,200 : if tam=0 {
repeat TAMAMAX
if tf.cnt>0 : continue
tf.cnt+ : tx.cnt=ex.ent : ty.cnt=ey.ent
rnd ts.cnt,5 : ts.cnt+=5
rnd tk.cnt,3 : if tk.cnt=0 : tk.cnt=1
dx=ex.ent-mx : if dx<0 : td.cnt=-3 : else : td.cnt=3
break
loop
}
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32
loop
return
*TAMAMOVE ;敵弾の移動＆当たり判定
repeat TAMAMAX
if tf.cnt<1 : continue
if tk.cnt=1 : ty.cnt+=ts.cnt : else : ty.cnt+=ts.cnt : tx.cnt-=td.cnt
if ty.cnt>480 : tf.cnt-
ent=cnt
repeat SHOTMAX
if sf.cnt=0 : continue
dx=(tx.ent+16)-(sx.cnt+16) : if dx<0 : dx=-dx
dy=(ty.ent+16)-(sy.cnt+16) : if dy<0 : dy=-dy
if dx<5 : if dy<10 {
tf.ent- : sf.cnt- : pos sx.cnt,sy.cnt : palcolor 255 : mes "●"
}
loop
if myl<1 : continue
dx=(tx.cnt+16)-(mx+32) : if dx<0 : dx=-dx
dy=(ty.cnt+16)-(my+32) : if dy<0 : dy=-dy
if dx<20 : if dy<30 {
tf.cnt- : myl- : ml- : gres+ : mmf=20 : gosub *MESSAGEBORN
}
pos tx.cnt,ty.cnt : gcopy 2,128,0,32,32
loop
return
*UFO ;UFO移動＆当たり判定
if uf<1 : return
ux+=usx : uy-=usy
if (usy<-10)|(usy>10) : us=-us
usy-=us
if (ux<160)|(ux>400) : usx=-usx
repeat SHOTMAX
if sf.cnt=0 : continue
dx=(ux+48)-(sx.cnt+16) : if dx<0 : dx=-dx
dy=(uy+16)-(sy.cnt+16) : if dy<0 : dy=-dy
if dx<20 : if dy<10 {
uf- : sf.cnt- : pos sx.cnt,sy.cnt : palcolor 255 : mes "●"
}
loop
pos ux,uy : gcopy 2,64,(ufn+1)*32,96,32
if gcnt\20<1 : ufn=ufn+1\2
if gcnt\300<1 : if myl>0 {
utf+ : utx=ux+48 : uty=uy+16 : if ux>300 : utsx=-utsx
}
return
*UFOTAMA ;UFOの弾移動＆当たり判定
if utf<1 : return
utx+=utsx : uty+=utsy
if uty>300 { if utx<200 : utsx+=10
if utx>400 : utsx-=10
} else {
if utx<250 : utsx+=8
if utx>350 : utsx-=8
}
if uty>480 : utf- : utsx=30
dx=(utx+32)-(mx+32) : if dx<0 : dx=-dx
dy=(uty+32)-(my+32) : if dy<0 : dy=-dy
if dx<20 : if dy<30 {
utf- : myl- : utsx=30
ml- : gres+ : mmf=20 : gosub *MESSAGEBORN
}
pos utx,uty : gcopy 2,0,0,32,32
return
*MESSAGEBORN ;メッセージ発生処理（爆風発生処理）
px=mx : py=my
return
*MESSAGE ;画面メッセージ＆爆風の表示
pos 0,457 : gzoom 32,32,2,0,32,64,96 : palcolor 255 : pos 30,458 : mes ml
if mmf>0 {
pos px,py : gcopy 3,mybomx*96,mybomy*96,96,96
mybomx=mybomx+1\8
if mybomx=7 : mybomy=1
mmf--
}
return
*GAMEOVER ;ゲームオーバー
end
↑こんな感じで自機がやられると爆風が出ます♪
ついでに画面左下に自機の残数表示も追加です(^^);
上手く出来たら、次に行ってみましょう♪
NEXT ->>